move IT Home Base

Prim Mover

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:42 +0000

Prim Mover

float   cnfSpeed        =   1.0;
string  cnfSitAnim      =   "backflip";
 
///////////////////////////////////////////////////////////////////////////
vector  velocity    =   <0,0,0>;
 
warpPos( vector destpos ){
    integer jumps = (integer)(llVecDist(destpos, llGetPos()) / 10.0) + 1;
 
    if (jumps > 100 )
        jumps = 100;
 
    list rules = [ PRIM_POSITION, destpos ];
 
    integer count = 1;
    while ( ( count = count << 1 ) < jumps)
        rules = (rules=[]) + rules + rules;
 
    llSetPrimitiveParams( rules + llList2List( rules, (count - jumps) << 1, count) );
 
    if ( llVecDist( llGetPos(), destpos ) > .001 )
        while ( --jumps )
            llSetPos( destpos );
}
 
default
{
 
    state_entry()
    {
        llSitTarget(<0,0,-110>,<0,0,0,0>);
        llSetCameraEyeOffset(<0.0, 0.0, -108>);
        llSetCameraAtOffset(<0.0, 0.0, -108>);
        llListen(4,"",llGetOwner(),"");
    }
 
    changed(integer c)
    {
        if(c & CHANGED_LINK && llAvatarOnSitTarget() == llGetOwner())
        {
            llRequestPermissions(llAvatarOnSitTarget(),PERMISSION_TRIGGER_ANIMATION | PERMISSION_TAKE_CONTROLS | PERMISSION_CONTROL_CAMERA);
            warpPos(llGetPos() + <0,0,110>);
        } else if(c & CHANGED_LINK && llAvatarOnSitTarget() == NULL_KEY){
            warpPos(llGetPos() - <0,0,110>);
        }
    }
 
    listen(integer c, string n, key id, string msg){
        cnfSpeed = (float)msg;
    }
 
    run_time_permissions(integer perm){
        if(perm & PERMISSION_TRIGGER_ANIMATION && llAvatarOnSitTarget() == llGetOwner()){
            llStopAnimation("Sit");
            llStartAnimation(cnfSitAnim);
        }
        if(perm & PERMISSION_TAKE_CONTROLS && llAvatarOnSitTarget() == llGetOwner()){
            llTakeControls(CONTROL_FWD | CONTROL_BACK | CONTROL_LEFT | CONTROL_RIGHT | CONTROL_UP | CONTROL_DOWN | CONTROL_ROT_LEFT | CONTROL_ROT_RIGHT,TRUE,FALSE);
        }
    }
 
    touch_start(integer n){
        llRequestPermissions(llAvatarOnSitTarget(),PERMISSION_TRIGGER_ANIMATION | PERMISSION_TAKE_CONTROLS | PERMISSION_CONTROL_CAMERA);
    }
 
    control(key id, integer held, integer change){
        rotation rot;
        if(held & CONTROL_FWD)
            velocity.x = velocity.x + cnfSpeed;
        else
            velocity.x *= 0.75;
 
        if(held & CONTROL_BACK)
            velocity.x = velocity.x - cnfSpeed;
        else
            velocity.x *= 0.75;
 
        if(held & CONTROL_LEFT)
            velocity.y = velocity.y - cnfSpeed;
        else
            velocity.y *= 0.75;
 
        if(held & CONTROL_RIGHT)
            velocity.y = velocity.y + cnfSpeed;
        else
            velocity.y *= 0.75;
 
        if(held & CONTROL_UP)
            llSetPos(llGetPos() + <0,0,cnfSpeed>);
 
        if(held & CONTROL_DOWN)
            llSetPos(llGetPos() + <0,0,-cnfSpeed>);
 
        if(held & CONTROL_ROT_LEFT)
        {
            rot = llGetRot() * llEuler2Rot(<0,0,0.12>);
            llSetRot(rot);
        }
 
        if(held & CONTROL_ROT_RIGHT)
        {
            rot = llGetRot() * llEuler2Rot(<0,0,-0.12>);
            llSetRot(rot);
        }
 
        llSetPos(velocity * llGetRot() + llGetPos());
    }
}

Avatar Trace Cam

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:38 +0000

Avatar Trace Cam

Überwachungskamera die automatisch in die Richtung zu einem Avatar zeigt.

default {
    state_entry()
    {
        llSetStatus(STATUS_PHYSICS,TRUE); // Gibt dem Objekt physikalische Eigenschaften.
        llSetHoverHeight(1.0,FALSE,1); // Das objekt schwebt einen Meter über dem Boden.
        llSensorRepeat("","",AGENT,10,PI,11); // Ein Sensor sucht nach Agenten im Umkeis von 10 Metern im 11 Sekunden Takt.
    }
 
    sensor(integer det)
    {
        vector pos = llDetectedPos(0); // Die Position des am nachsten stehenden Avatars wird zugewiesen.
        llLookAt(pos,1,1); // Das Objekt zeigt in Richtung des Avatars.
    }
}

Binary Clock

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:38 +0000

Binary Clock

// Binary Clock Script
// By Fox Diller
// OMG INSANITY!
 
list bTime;
list oTime;
 
integer token;
 
string dec2bin(integer dec)
{
    if (dec == 0) return "0000";
    if (dec == 1) return "0001";
    if (dec == 2) return "0010";
    if (dec == 3) return "0011";
    if (dec == 4) return "0100";
    if (dec == 5) return "0101";
    if (dec == 6) return "0110";
    if (dec == 7) return "0111";
    if (dec == 8) return "1000";
    if (dec == 9) return "1001";
    return "0000";
}
 
BuildClock()
{
    integer shiftraw = (integer)llGetWallclock();
 
    integer hours = shiftraw / 3600;
    integer minutes = (shiftraw % 3600) / 60;
    integer seconds = shiftraw % 60;
 
    bTime = [hours   / 10, hours   % 10,
             minutes / 10, minutes % 10,
             seconds / 10, seconds % 10];
 
}
 
displayBDC()
{
    integer current_rowA = llList2Integer(bTime, 0);
    integer old_rowA = llList2Integer(oTime, 0);
    if (current_rowA != old_rowA)
    {
        string rowA = dec2bin(current_rowA);
        integer Acol0 = (integer)llGetSubString(rowA, 3, 3);
        integer Acol1 = (integer)llGetSubString(rowA, 2, 2); 
        llMessageLinked(2, Acol0, "", "");
        llMessageLinked(3, Acol1, "", "");
    } else if (!current_rowA) {
        llMessageLinked(2, 0, "", "");
        llMessageLinked(3, 0, "", "");
    }
 
    integer current_rowB = llList2Integer(bTime, 1);
    integer old_rowB = llList2Integer(oTime, 1);
    if (current_rowB != old_rowB)
    {
        string rowB = dec2bin(current_rowB);
        integer Bcol0 = (integer)llGetSubString(rowB, 3, 3);
        integer Bcol1 = (integer)llGetSubString(rowB, 2, 2);
        integer Bcol2 = (integer)llGetSubString(rowB, 1, 1);
        integer Bcol3 = (integer)llGetSubString(rowB, 0, 0); 
        llMessageLinked(4, Bcol0, "", "");
        llMessageLinked(5, Bcol1, "", "");
        llMessageLinked(6, Bcol2, "", "");
        llMessageLinked(7, Bcol3, "", "");
    } else if (!current_rowB) {
        llMessageLinked(4, 0, "", "");
        llMessageLinked(5, 0, "", "");
        llMessageLinked(6, 0, "", "");
        llMessageLinked(7, 0, "", "");
    }
 
 
    integer current_rowC = llList2Integer(bTime, 2);
    integer old_rowC = llList2Integer(oTime, 2);
    if (current_rowC != old_rowC)
    {     
        string rowC = dec2bin(current_rowC);
        integer Ccol0 = (integer)llGetSubString(rowC, 3, 3);
        integer Ccol1 = (integer)llGetSubString(rowC, 2, 2);
        integer Ccol2 = (integer)llGetSubString(rowC, 1, 1);
        llMessageLinked(8, Ccol0, "", "");
        llMessageLinked(9, Ccol1, "", "");
        llMessageLinked(10, Ccol2, "", "");
    } else if (!current_rowC) {
        llMessageLinked(8, 0, "", "");
        llMessageLinked(9, 0, "", "");
        llMessageLinked(10, 0, "", "");
    }
 
    integer current_rowD = llList2Integer(bTime, 3);
    integer old_rowD = llList2Integer(oTime, 3);
    if (current_rowD != old_rowD)
    {
        string rowD = dec2bin(current_rowD);
        integer Dcol0 = (integer)llGetSubString(rowD, 3, 3);
        integer Dcol1 = (integer)llGetSubString(rowD, 2, 2);
        integer Dcol2 = (integer)llGetSubString(rowD, 1, 1);
        integer Dcol3 = (integer)llGetSubString(rowD, 0, 0); 
        llMessageLinked(11, Dcol0, "", "");
        llMessageLinked(12, Dcol1, "", "");
        llMessageLinked(13, Dcol2, "", "");
        llMessageLinked(14, Dcol3, "", "");
    } else if (!current_rowD) {
        llMessageLinked(11, 0, "", "");
        llMessageLinked(12, 0, "", "");
        llMessageLinked(13, 0, "", "");
        llMessageLinked(14, 0, "", "");
    }
 
    integer current_rowE = llList2Integer(bTime, 4);
    integer old_rowE = llList2Integer(oTime, 4);
    if (current_rowE != old_rowE)
    {
        string rowE = dec2bin(current_rowE);
        integer Ecol0 = (integer)llGetSubString(rowE, 3, 3);
        integer Ecol1 = (integer)llGetSubString(rowE, 2, 2);
        integer Ecol2 = (integer)llGetSubString(rowE, 1, 1);
        llMessageLinked(15, Ecol0, "", "");
        llMessageLinked(16, Ecol1, "", "");
        llMessageLinked(17, Ecol2, "", "");
    } else if (!current_rowE) {
        llMessageLinked(15, 0, "", "");
        llMessageLinked(16, 0, "", "");
        llMessageLinked(17, 0, "", "");
    }
 
    integer current_rowF = llList2Integer(bTime, 5);
    integer old_rowF = llList2Integer(oTime, 5);
    if (current_rowF != old_rowF)
    {
        string rowF = dec2bin(current_rowF);
        integer Fcol0 = (integer)llGetSubString(rowF, 3, 3);
        integer Fcol1 = (integer)llGetSubString(rowF, 2, 2);
        integer Fcol2 = (integer)llGetSubString(rowF, 1, 1);
        integer Fcol3 = (integer)llGetSubString(rowF, 0, 0); 
        llMessageLinked(18, Fcol0, "", "");
        llMessageLinked(19, Fcol1, "", "");
        llMessageLinked(20, Fcol2, "", "");
        llMessageLinked(21, Fcol3, "", "");
    } else if (!current_rowF) {
        llMessageLinked(18, 0, "", "");
        llMessageLinked(19, 0, "", "");
        llMessageLinked(20, 0, "", "");
        llMessageLinked(21, 0, "", "");
    }
 
}
 
default
{
    touch_start(integer total_number)
    {
        if (!token && llDetectedKey(0) == llGetOwner())
        {
            oTime = [];
            bTime = [];
            llSetTimerEvent(1.0);
            token = 1;
            llOwnerSay("On!");
        }
 
        else if (token && llDetectedKey(0) == llGetOwner())
        {
            llSetTimerEvent(0);
            token = 0;
            llOwnerSay("Off!");
        }
    }
 
    timer()
    {
        bTime = oTime;
        BuildClock();
        displayBDC();
    }
}

Simple Radar

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:43 +0000

Simple Radar

//Sable Till - Radar/scannar script.
//You can get a copy of the license this script is under at http://www.gnu.org/copyleft/gpl.html
//Copyright (C) 2006 Sable Till

//This program is free software; you can redistribute it and/or
//modify it under the terms of the GNU General Public License
//as published by the Free Software Foundation; either version 2
//of the License, or (at your option) any later version.

//This program is distributed in the hope that it will be useful,
//but WITHOUT ANY WARRANTY; without even the implied warranty of
//MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
//GNU General Public License for more details.

//You should have received a copy of the GNU General Public License
//along with this program; if not, write to the Free Software
//Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

string status="none";
list people;
integer maxScanDistance;
vector color = <0,1,1>;
integer maxPeople = 8;
integer scanType = AGENT;
integer scanFreq=1;

integer count(string name) {
integer i = llListFindList(people, [name]);
if(i ==-1){
people+=[name, 0];
return 0;
} else {
integer count = llList2Integer(people, i+1);
people=llListReplaceList(people, [count+scanFreq], i+1, i+1);
return count;
}
}

//calculate time strings with proper units that are sensibly rounded
string time(integer cnt) {
if(cnt>3600) {
return (string)(cnt/3600)+"hr " + (string)((cnt%3600)/60) +"min";
}else {
if(cnt>60) {
return (string)(cnt/60)+"min";
} else {
return (string)cnt+"s";
}
}
}

//I'm pretty sure there's a better way to do this but I'm trying to calculate the angle between
//North and the target so I can work out which direction it is in.
float getAngle(vector me, vector target) {
float hyp = llVecDist(me, target);
float yDiff = target.y-me.y;
float xDiff = target.x-me.x;
float angle = llSin(yDiff/hyp);
if(xDiff>0 && yDiff>0) {
return angle*RAD_TO_DEG;
}
if(xDiff>0 && yDiff<0) {
return 90-angle*RAD_TO_DEG;
}
if(xDiff<0 && yDiff>0) {
return angle*RAD_TO_DEG+270;
}
if(xDiff<0 && yDiff<0) {
return angle*RAD_TO_DEG + 270;
}
return angle*RAD_TO_DEG;
}

default
{
state_entry()
{
llSensorRepeat("", "",scanType, 96, PI, scanFreq);
llSetTimerEvent(6);
}

sensor(integer num_detected) {
people=[];
string result;
integer n=-1;
integer distance=0;
integer detDist;
string name;

vector pos = llGetPos();
//get the dist, name and direction of everyone we just scanned.
for(n=0;n<num_detected && n<maxPeople;++n) {
vector detPos = llDetectedPos(n);
detDist = (integer)llVecDist(pos, detPos);
float angle = getAngle(llGetPos(), detPos);
name = llKey2Name(llDetectedKey(n));
if(detDist<96) {
people+=detDist;
people+=name;
people+=angle;
}
}
//sort the strided list
people = llListSort(people, 3, TRUE);
//construct settext
num_detected = llGetListLength(people)/3;
for(n=0;n<num_detected;++n) {
detDist=llList2Integer(people, n*3);
name = llList2String(people, n*3+1);
float dir = llList2Float(people, n*3+2);
if(detDist>20 && distance<=20) {
result+="<- Chat Range Limit ->\n";
}
result+=name;
if(detDist<20) {
integer cnt = count(name);
result+=" ["+time(cnt)+"]";
}
result+=" ["+(string)detDist+"m]";

if(dir < 0 || dir > 360) {
llOwnerSay("Error:"+(string)dir+":"+name);
}
//determine which compass direction they are in.
if(dir <= 22.5) {
result+=" N\n";
} else {
if(dir > 22.5 && dir <= 67.5) {
result+=" NE\n";
} else {
if(dir > 67.5 && dir <= 112.5) {
result+=" E\n";
} else {
if(dir > 112.5 && dir <= 157.5) {
result+=" SE\n";
} else {
if(dir > 157.5 && dir <= 202.5) {
result+=" S\n";
} else {
if(dir > 202.5 && dir <= 247.5) {
result+=" SW\n";
} else {
if(dir > 247.5 && dir <= 292.5) {
result+=" W\n";
} else {
if(dir > 292.5 && dir <= 337.5) {
result+=" NW\n";
} else {
if(dir > 337.5 && dir < 360) {
result+=" N\n";
}
}
}

}}}}}}

distance=detDist;
}


//If we detected more (or the same number of) people as maxPeople then shrink down the scan distance to just
//the distance to the furthest one. Otherwise increment it a bit in case there are people further out.
if(num_detected>=maxPeople) {
maxScanDistance=distance+10;
} else {
maxScanDistance+=10;
}

result+="\nStatus:"+status;
//adjust max people based on the length of result
if(llStringLength(result)>254) {
maxPeople--;
llOwnerSay("Length is "+(string)llStringLength(result) +
" Decrementing maxPeople to "+(string)maxPeople);
} else {
if(llStringLength(result)<200 && num_detected>maxPeople) {
maxPeople++;
llOwnerSay("Length is "+(string)llStringLength(result) +
" Incrementing maxPeople to "+(string)maxPeople);
}
}
llSetText(result, color, 1);
}

no_sensor() {
llSetText("Status:"+status, color, 1);
maxScanDistance+=10;
llSensorRepeat("", "", scanType, maxScanDistance, PI, scanFreq);
}

//all we do here is check the sims fps and dilation and tone down our scanning if necessary.
timer() {
float fps = llGetRegionFPS();
float timeDilation = llGetRegionTimeDilation();

integer scanDistance;
if(fps<35 || timeDilation <0.9) {
if(maxScanDistance>30) {
scanDistance=30;
}
scanFreq=240;
status = "poor";
llSetTimerEvent(240);
color=<1,0,0>;
} else
{
if(fps<40 || timeDilation<0.95) {
if(maxScanDistance>64) {
scanDistance=64;
} else {
scanDistance=maxScanDistance;
}
scanFreq=30;
status = "ok";
llSetTimerEvent(120);
color=<1,1,0>;
} else
{
if(maxScanDistance>96) {
scanDistance=96;
} else {
scanDistance=maxScanDistance;
}
scanFreq=1;
llSetTimerEvent(60);
status = "good";
color=<0,1,1>;
}}
llSensorRepeat("", "", scanType, scanDistance, PI, scanFreq);
}

}

Teleport

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:44 +0000

Teleport

//Teleport v2.02 by Pablo Pharmanaut
//based on code by Cubey Terra

integer totalPos = 4;                    //This integer should equal total number of positions
integer currentPos = 1;
string currentpos;

vector vPos1 = <117,152,22>;             //These are vectors for the positions to
vector vPos2 = <81,23, 103>;             //which you wish to teleport
vector vPos3 = <83, 49.00, 29>;
vector vPos4 = <67,120,22>;
//vector vPos5 = <143.3,238.8,50.2>;

string sPos1 = "Position One";           //name of positions, if desired.  This helps
string sPos2 = "Position Two";           //you to know where you are going!
string sPos3 = "Position Three";
string sPos4 = "Position Four";
//string sPos5 = "Position Five";

vector currentvPos;

setPos()
{
    if (currentPos == 1)
    {
        currentpos = sPos1;
        currentvPos = vPos1;
    }
    else if (currentPos == 2)             
    {                                     
        currentpos = sPos2;               
        currentvPos = vPos2;             
    }                                     
    else if (currentPos == 3)
    {
        currentpos = sPos3;
        currentvPos = vPos3;
    }
    else if (currentPos == 4)
    {
        currentpos = sPos4;
        currentvPos = vPos4;
    }
//  else if (currentPos == 5)
//  {
//      currentpos = sPos5;
//      currentvPos = vPos5;
//  }
   
    //add else if section here with higher currentPos integer to add TP destinations.
    //Don't forget to increase totalPos integer at top of script

    vector pos = llGetPos();
    llSetText("Teleport to "+currentpos+"\nTouch me to change destination",<1,1,1>,1.0);
    vector offset = currentvPos - pos;
    llSitTarget(offset, ZERO_ROTATION);
}

default
{
    state_entry()
    {
        llSetSitText("Teleport");            //This changes HUD display from "sit" to "Teleport"
    }
    touch_start(integer total_number)
    {
        currentPos += 1;
        if (currentPos > totalPos) currentPos = 1;
        setPos();
    }
    changed(integer change)
    {
        if ((change & CHANGED_LINK)==CHANGED_LINK)
        {
            if (llAvatarOnSitTarget() != NULL_KEY)
            {
                llUnSit(llAvatarOnSitTarget());
            }
        }
    }
}

Texture Dropper

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:44 +0000

Texture Dropper

// **** Texture Dropper Screen v1.11, by Mircea Kitsune & Sm0key ****

// -------- Settings: --------
// Modify these to adjust the properties of your screen. Unless a specific value is required, use TRUE or FALSE.

integer face = 0; //Primitive face to be used as screen.
integer text = 2; //0 means no text, 1 displays lock status, 2 displays lock status and image + creator names. Selecting 2 clears the image between script restarts.
integer notices = TRUE; //Echo information such as locking / unlocking of the screen and error messages in-world.

integer lockdefault = FALSE; //Set to TRUE if the screen is to be locked by default. Relevant in the case of script restarts and when using the "clear" command.
integer lockonpost = FALSE; //If TRUE the screen is locked once someone posts the first picture in it, useful for 'find and claim' screens.
    integer creatorlock = TRUE; //When lockonpost is also TRUE, this allows the creator of the displayed image to lock / unlock or clear the screen.

string screenname = "screen"; //The name which best describes what your object is, used for info and text display (eg: screen, painting, monitor).
string sound = ""; //A sound to be played each time a new image is posted. Leave this string empty to disable sounds.
    float soundvol = 1; //Volume of the sound specified above, can be anything between 0 and 1.

// -------- Script: --------
// Modify anything below if you are a scripter and want to change something else in the script.

string ScriptName;
string InvName;
string InvCreator;
string Toucher;

string Blank = "5748decc-f629-461c-9a36-a35a221fe21f"; //UUID of the blank texture.
integer CmdChan = 9945; //System channel for llDialog.

default
{
    state_entry()
    {
        ScriptName = llGetScriptName();
        llPreloadSound(sound);
        if(text == 2) //Set texture to blank when names are used to avoid images with no names between script restarts.
        {
            llSetTexture(Blank, face);
            llPlaySound(sound, soundvol);
        }
        else if(text != 1 | text != 2)
        {
            llSetText("", <0,0,0>, 0);
        }
       
        if(lockdefault == TRUE)
        {
            state locked;
        }
        else
        {
            state unlocked;
        }
    }
}

state locked
{
    state_entry()
    {
        llAllowInventoryDrop(0);
        llListen(CmdChan, "", NULL_KEY, "" );
        if(notices == 1)
        {
            llSay(0, "The " + screenname + " is now locked.");
        }
       
        if(text == 2 & InvName != "")
        {
            llSetText("[" + screenname + " locked] - " + InvName + " by " + InvCreator, <1,0.5,0.5>, 1);
        }
        else if(text == 1 | text == 2 & InvName == "")
        {
            llSetText("[" + screenname + " locked]", <1,0.5,0.5>, 1);
        }
    }
   
    touch_start(integer avatar)
    {
        Toucher = llDetectedKey(0);
        llSetTimerEvent(15);
        if (Toucher == llGetOwner())
        {
            llDialog(llDetectedKey(0) , "You are the owner of this screen. What do you wish to do?", ["unlock", "clear"], CmdChan);
        }
        else if(lockonpost == TRUE & creatorlock == TRUE & llKey2Name(Toucher) == InvCreator)
        {
            llDialog(llDetectedKey(0) , "You have been identified as the creator of the currently posted image. What do you wish to do?", ["unlock", "clear"], CmdChan);
        }
        else
        {
            llSay(0, "The " + screenname + " is locked. The owner must first unlock it before you can display new pictures.");
        }
    }
   
    listen(integer channel, string name, key id, string message)
    {
        if(Toucher == llGetOwner() | lockonpost == TRUE & creatorlock == TRUE & llKey2Name(Toucher) == InvCreator)
        {
            Toucher = ""; //Protection so if an owner was the last to touch the object not anyone is able to manually chat an owner-only command on the channel.
            if(llToLower(message) == "unlock")
            {
                state unlocked;
            }
            if(llToLower(message) == "clear")
            {
                llSetTexture(Blank, face);
                llPlaySound(sound, soundvol);
                InvName = "";
                InvCreator = "";
                if(lockdefault == TRUE)
                {
                    llSetText("[" + screenname + " locked]", <1,0.5,0.5>, 1);
                }
                else
                {
                    state unlocked;
                }
            }               
        }
    }
   
    timer()
    {
        Toucher = ""; //Further protection so if an owner ignores the dialog the screen does not remain vulnerable for anyone to chat an owner-only command to.
        llSetTimerEvent(0);
    }
}

state unlocked
{
    state_entry()
    {
        llAllowInventoryDrop(1);
        llListen(CmdChan, "", NULL_KEY, "" );
        if(notices == 1)
        {
            llSay(0, "The " + screenname + " is now unlocked.");
        }
       
        if(text == 2 & InvName != "")
        {
            llSetText("[" + screenname + " unlocked] - " + InvName + " by " + InvCreator, <0.5,1,0.5>, 1);
        }
        else if(text == 1 | text == 2 & InvName == "")
        {
            llSetText("[" + screenname + " unlocked]", <0.5,1,0.5>, 1);
        }
    }
   
    changed(integer mask)
    {
        if(mask & (CHANGED_ALLOWED_DROP | CHANGED_INVENTORY))
        {
            if(llGetInventoryNumber(0)) //Texture dropped
            {
                InvName = llGetInventoryName(INVENTORY_TEXTURE, 0);
                key InvKey = llGetInventoryKey(InvName);
                InvCreator = llKey2Name(llGetInventoryCreator(InvName));
                llRemoveInventory(InvName);
                llSetTexture(InvKey, face);
                llPlaySound(sound, soundvol);
                if(lockonpost == TRUE)
                {
                    state locked;
                }
                else if(text == 2)
                {
                    llSetText("[" + screenname + " unlocked] - " + InvName + " by " + InvCreator, <0.5,1,0.5>, 1);
                }
            }
            else //Something else dropped
            {
                integer Items = llGetInventoryNumber(-1);
                do
                {
                    string InvName = llGetInventoryName(INVENTORY_ALL, --Items);
                    if (InvName != ScriptName & InvName != sound)
                    {
                        llRemoveInventory(InvName);
                        if(notices == 1)
                        {
                            llSay(0, "Error - Only textures may be dropped inside the " + screenname + ".");
                        }
                    }
                }
                while(Items);
            }
        }
    }
   
    touch_start(integer avatar)
    {
        Toucher = llDetectedKey(0);
        llSetTimerEvent(15);
        if (Toucher == llGetOwner())
        {
            llDialog(llDetectedKey(0) , "You are the owner of this screen. What do you wish to do?", ["lock", "clear"], CmdChan);
        }
        else if(lockonpost == TRUE & creatorlock == TRUE & llKey2Name(Toucher) == InvCreator)
        {
            llDialog(llDetectedKey(0) , "You have been identified as the creator of the currently posted image. What do you wish to do?", ["lock", "clear"], CmdChan);
        }
        else
        {
            llSay(0, "The " + screenname + " is unlocked. Control + drag textures onto it to display them.");
        }
    }
   
    listen(integer channel, string name, key id, string message)
    {
        if(Toucher == llGetOwner() | lockonpost == TRUE & creatorlock == TRUE & llKey2Name(Toucher) == InvCreator)
        {
            Toucher = ""; //Protection so if an owner was the last to touch the object not anyone is able to manually chat an owner-only command on the channel.
            if(llToLower(message) == "lock")
            {
                state locked;
            }
            if(llToLower(message) == "clear")
            {
                llSetTexture(Blank, face);
                llPlaySound(sound, soundvol);
                InvName = "";
                InvCreator = "";
                if(lockdefault == TRUE)
                {
                    state locked;
                }
                else
                {
                    llSetText("[" + screenname + " unlocked]", <0.5,1,0.5>, 1);
                }
            }               
        }
    }
   
    timer()
    {
        Toucher = ""; //Further protection so if an owner ignores the dialog the screen does not remain vulnerable for anyone to chat an owner-only command to.
        llSetTimerEvent(0);
    }
}