move IT Home Base

Animationen

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:45 +0000

Animationen

Binary Clock

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:38 +0000

Binary Clock

// Binary Clock Script
// By Fox Diller
// OMG INSANITY!
 
list bTime;
list oTime;
 
integer token;
 
string dec2bin(integer dec)
{
    if (dec == 0) return "0000";
    if (dec == 1) return "0001";
    if (dec == 2) return "0010";
    if (dec == 3) return "0011";
    if (dec == 4) return "0100";
    if (dec == 5) return "0101";
    if (dec == 6) return "0110";
    if (dec == 7) return "0111";
    if (dec == 8) return "1000";
    if (dec == 9) return "1001";
    return "0000";
}
 
BuildClock()
{
    integer shiftraw = (integer)llGetWallclock();
 
    integer hours = shiftraw / 3600;
    integer minutes = (shiftraw % 3600) / 60;
    integer seconds = shiftraw % 60;
 
    bTime = [hours   / 10, hours   % 10,
             minutes / 10, minutes % 10,
             seconds / 10, seconds % 10];
 
}
 
displayBDC()
{
    integer current_rowA = llList2Integer(bTime, 0);
    integer old_rowA = llList2Integer(oTime, 0);
    if (current_rowA != old_rowA)
    {
        string rowA = dec2bin(current_rowA);
        integer Acol0 = (integer)llGetSubString(rowA, 3, 3);
        integer Acol1 = (integer)llGetSubString(rowA, 2, 2); 
        llMessageLinked(2, Acol0, "", "");
        llMessageLinked(3, Acol1, "", "");
    } else if (!current_rowA) {
        llMessageLinked(2, 0, "", "");
        llMessageLinked(3, 0, "", "");
    }
 
    integer current_rowB = llList2Integer(bTime, 1);
    integer old_rowB = llList2Integer(oTime, 1);
    if (current_rowB != old_rowB)
    {
        string rowB = dec2bin(current_rowB);
        integer Bcol0 = (integer)llGetSubString(rowB, 3, 3);
        integer Bcol1 = (integer)llGetSubString(rowB, 2, 2);
        integer Bcol2 = (integer)llGetSubString(rowB, 1, 1);
        integer Bcol3 = (integer)llGetSubString(rowB, 0, 0); 
        llMessageLinked(4, Bcol0, "", "");
        llMessageLinked(5, Bcol1, "", "");
        llMessageLinked(6, Bcol2, "", "");
        llMessageLinked(7, Bcol3, "", "");
    } else if (!current_rowB) {
        llMessageLinked(4, 0, "", "");
        llMessageLinked(5, 0, "", "");
        llMessageLinked(6, 0, "", "");
        llMessageLinked(7, 0, "", "");
    }
 
 
    integer current_rowC = llList2Integer(bTime, 2);
    integer old_rowC = llList2Integer(oTime, 2);
    if (current_rowC != old_rowC)
    {     
        string rowC = dec2bin(current_rowC);
        integer Ccol0 = (integer)llGetSubString(rowC, 3, 3);
        integer Ccol1 = (integer)llGetSubString(rowC, 2, 2);
        integer Ccol2 = (integer)llGetSubString(rowC, 1, 1);
        llMessageLinked(8, Ccol0, "", "");
        llMessageLinked(9, Ccol1, "", "");
        llMessageLinked(10, Ccol2, "", "");
    } else if (!current_rowC) {
        llMessageLinked(8, 0, "", "");
        llMessageLinked(9, 0, "", "");
        llMessageLinked(10, 0, "", "");
    }
 
    integer current_rowD = llList2Integer(bTime, 3);
    integer old_rowD = llList2Integer(oTime, 3);
    if (current_rowD != old_rowD)
    {
        string rowD = dec2bin(current_rowD);
        integer Dcol0 = (integer)llGetSubString(rowD, 3, 3);
        integer Dcol1 = (integer)llGetSubString(rowD, 2, 2);
        integer Dcol2 = (integer)llGetSubString(rowD, 1, 1);
        integer Dcol3 = (integer)llGetSubString(rowD, 0, 0); 
        llMessageLinked(11, Dcol0, "", "");
        llMessageLinked(12, Dcol1, "", "");
        llMessageLinked(13, Dcol2, "", "");
        llMessageLinked(14, Dcol3, "", "");
    } else if (!current_rowD) {
        llMessageLinked(11, 0, "", "");
        llMessageLinked(12, 0, "", "");
        llMessageLinked(13, 0, "", "");
        llMessageLinked(14, 0, "", "");
    }
 
    integer current_rowE = llList2Integer(bTime, 4);
    integer old_rowE = llList2Integer(oTime, 4);
    if (current_rowE != old_rowE)
    {
        string rowE = dec2bin(current_rowE);
        integer Ecol0 = (integer)llGetSubString(rowE, 3, 3);
        integer Ecol1 = (integer)llGetSubString(rowE, 2, 2);
        integer Ecol2 = (integer)llGetSubString(rowE, 1, 1);
        llMessageLinked(15, Ecol0, "", "");
        llMessageLinked(16, Ecol1, "", "");
        llMessageLinked(17, Ecol2, "", "");
    } else if (!current_rowE) {
        llMessageLinked(15, 0, "", "");
        llMessageLinked(16, 0, "", "");
        llMessageLinked(17, 0, "", "");
    }
 
    integer current_rowF = llList2Integer(bTime, 5);
    integer old_rowF = llList2Integer(oTime, 5);
    if (current_rowF != old_rowF)
    {
        string rowF = dec2bin(current_rowF);
        integer Fcol0 = (integer)llGetSubString(rowF, 3, 3);
        integer Fcol1 = (integer)llGetSubString(rowF, 2, 2);
        integer Fcol2 = (integer)llGetSubString(rowF, 1, 1);
        integer Fcol3 = (integer)llGetSubString(rowF, 0, 0); 
        llMessageLinked(18, Fcol0, "", "");
        llMessageLinked(19, Fcol1, "", "");
        llMessageLinked(20, Fcol2, "", "");
        llMessageLinked(21, Fcol3, "", "");
    } else if (!current_rowF) {
        llMessageLinked(18, 0, "", "");
        llMessageLinked(19, 0, "", "");
        llMessageLinked(20, 0, "", "");
        llMessageLinked(21, 0, "", "");
    }
 
}
 
default
{
    touch_start(integer total_number)
    {
        if (!token && llDetectedKey(0) == llGetOwner())
        {
            oTime = [];
            bTime = [];
            llSetTimerEvent(1.0);
            token = 1;
            llOwnerSay("On!");
        }
 
        else if (token && llDetectedKey(0) == llGetOwner())
        {
            llSetTimerEvent(0);
            token = 0;
            llOwnerSay("Off!");
        }
    }
 
    timer()
    {
        bTime = oTime;
        BuildClock();
        displayBDC();
    }
}

Radio

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:42 +0000

Radio

Mit diesem Script kann man durch klicken auf ein Prim die Musik auf einer Region ein-, aus- und umschalten. Die Zulieferer der Musik können auf die eigenen Wünsche angepasst werden.

integer totalNum = 4;
integer currentNum = 1;
string currentstation;
string currenturl;
 
string id1 = "Radio Off";
string id2 = "Grateful Dead Radio";
string id3 = "Sky.FM Roots Reggae";
string id4 = "Sky.FM Bossanova";
string id5 = "KTRU Radio";
string url1 = "";
string url2 = "http://gdradio.radioserver.co.uk:8160/";
string url3 = "http://205.188.215.225:8000";
string url4 = "http://160.79.128.40:7804";
string url5 = "http://128.42.33.17:80/";
 
setNumber()
{
    if (currentNum == 1)
    {
        currentstation = id1;
        currenturl = url1;
    }
    else if (currentNum == 2)
    {
        currentstation = id2;
        currenturl = url2;
    }
    else if (currentNum == 3)
    {
        currentstation = id3;
        currenturl = url3;
    }
    else if (currentNum == 4)
    {
        currentstation = id4;
        currenturl = url4;
    }
    else if (currentNum == 5)
    {
        currentstation = id5;
        currenturl = url5;
    }
    llSetText(currentstation, <1,1,1>,1.0);
    llSetParcelMusicURL(currenturl);
   
}
 
default
{
    state_entry()
    {
        llSetText("Radio",<1,1,1>,1.0);
    }
    touch_start(integer total_number)
    {
    currentNum += 1;
    if (currentNum > totalNum) currentNum = 1;
    setNumber();
    }
}

Skype Online Status

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:43 +0000

Skype Online Status

string skype_handle = "PUT-SKYPE-NAME-HERE";

key skype_request_id = NULL_KEY; // id of http request

showStatus(string skype_status)
{
    // build up our message
    string message = "Skype";
    message += "\nName: " + skype_handle;
    message += "\nStatus: " + skype_status;
    
    // write out the message as hovering text
    llSetText(message, <.5,.5,1>, 1);
}
default
{
    touch_start(integer total_number)
    {
        // make sure owner has specified handle
        if(skype_handle == "")
        {
            // send message to debugger
            llWhisper(DEBUG_CHANNEL, "skype_handle can not be empty.");
            return;
        }
        
        // prevent extra requests happening at the same time
        if(skype_request_id != NULL_KEY) return;
        
        // make a request over the internet
        skype_request_id = llHTTPRequest("http://mystatus.skype.com/" + skype_handle + ".txt", [HTTP_METHOD, "GET"], "");
        
        // set a timeout for http request
        llSetTimerEvent(5);
    }
    http_response(key request_id, integer status, list metadata, string body)
    {
        // is this a response to our request?
        if(request_id == skype_request_id) 
        {
            // show status
            showStatus(body);
            
            // change to view state
            state viewing;
        }

    }
    timer()
    {
        // didn't get a response in time.
        showStatus("No Response");
        
        // change to view state
        state viewing;
    }
}
state viewing
{
    state_entry()
    {
        // set next timer for 3 minutes
        llSetTimerEvent(180);
    }
    timer()
    {
        state default;
    }
    state_exit()
    {
        // stop the timer
        llSetTimerEvent(0);

        // hide the text
        llSetText("", ZERO_VECTOR, 0);
        
        // reset the request id
        skype_request_id = NULL_KEY;
    }
}

Skype Online Status - Multi-User Version

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:43 +0000

Skype Online Status - Multi-User Version

// zwischen die Anführungszeichen Deinen Skype-Name einfügen
string skype_handle = "";
// you are done!  no more changes!

key     notecode;
string  notecard;
integer noteline;
key skype_request_id = NULL_KEY; // id of http request

showStatus(string skype_status)
{
    // build up our message
    string message = "Skype";
    message += "\nName: " + skype_handle;
    message += "\nStatus: " + skype_status;
    
    // write out the message as hovering text
    llSetText(message, <.5,.5,1>, 1);
}

// AMD64 ADD: readnotecard() liest eine zeile
// Im Dataserver Event wird die gewünschte Variable dann gefüllt
// Sollte einmal beim rezzen/reseten und Inventory Change durchgeführt werden
readnotecard()
{
    // Der name der NC ist egal
    notecard = llGetInventoryName(INVENTORY_NOTECARD, 0);
    // Wenn aber keine da ist, setze die Variable auch auf leer und beende das ganze
    if (notecard == "")
    {
        skype_handle = "";
        return;
    }
    // Lesen beginnen bei Zeile Null (anfang)
    noteline = 0;
    // Ab hier gehts im Dataserver Event weiter
    notecode = llGetNotecardLine(notecard, noteline);
}

default
{
    on_rez(integer start_param)
    {
        readnotecard();
    }
    state_entry()
    {
        llSetTimerEvent(0);
        readnotecard();
    }
    changed(integer change)
    {
        // Änderung im Inventar des Objekts
        if (change & CHANGED_INVENTORY)
        {
            // NC am besten neu einlesen
            readnotecard();
        }
    }
    dataserver(key queryid, string data)
    {
        if (queryid == notecode)
        {
            // Für den Fall dass die NC leer ist
            if (data != EOF) 
            {
                skype_handle = data;
            }
            else
            {
                skype_handle = "";
            }
        }
    }
    touch_start(integer total_number)
    {
        // make sure owner has specified handle
        if(skype_handle == "")
        {
            // send message to debugger
            llWhisper(DEBUG_CHANNEL, "skype_handle can not be empty.");
            return;
        }
        
        // prevent extra requests happening at the same time
        if(skype_request_id != NULL_KEY) return;
        
        // make a request over the internet
        skype_request_id = llHTTPRequest("http://mystatus.skype.com/" + skype_handle + ".txt", [HTTP_METHOD, "GET"], "");
        
        // set a timeout for http request
        llSetTimerEvent(5);
    }
    http_response(key request_id, integer status, list metadata, string body)
    {
        // is this a response to our request?
        if(request_id == skype_request_id) 
        {
            // show status
            showStatus(body);
            
            // change to view state
            state viewing;
        }

    }
    timer()
    {
        // Didn't get a response in time.
        showStatus("No Response");
        
        // change to view state
        state viewing;
    }
}
state viewing
{
    state_entry()
    {
        // Set next timer for 3 minutes
        llSetTimerEvent(180);
    }
    timer()
    {
        state default;
    }
    state_exit()
    {
        // stop the timer
        llSetTimerEvent(0);

        // hide the text
        llSetText("", ZERO_VECTOR, 0);
        
        // reset the request id
        skype_request_id = NULL_KEY;
    }
}

Sleep

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:44 +0000

Sleep

Schlaf-Stellung.

// Francis wuz here
integer broadcast = 20;

// A More Neutral Sleeping Position
//vector target = <-1.06585, 0.71774, 0.18293>;
//rotation targetRot = <0.50028, -0.49972, -0.50028, 0.49972>;

// A More relaxed sleeping position
vector target = <-1.15419, 0.56328, -0.25744>;
rotation targetRot = <0.52105, -0.49829, -0.46875, 0.51038>;

integer debugRotation = FALSE;
key sitAgent = NULL_KEY;
integer gotPermission = FALSE;

integer time = 0;
default
{
    state_entry()
    {
        llSetSitText( "Sleep" );
        llSitTarget( target, targetRot );
        if ( debugRotation ) {
            llListen( 1977, "Rotation Broadcaster", NULL_KEY, "" );
            llListen( 1978, "Rotation Broadcaster", NULL_KEY, "" );
        }
    }
    listen(integer channel, string name, key id, string message ) {
        if ( channel == 1977 )
            targetRot = (rotation) message;
        else
            target = (vector) message;
            
        llSitTarget( target, targetRot ); 
        if ( time == 0 )
            llSay(0, (string) targetRot + ", " + (string)target );
        time = (time +1) % 50;
    }
    changed(integer change) {
        if (change & CHANGED_LINK)
        {
            key agent = llAvatarOnSitTarget();
            if ( sitAgent == NULL_KEY && agent != NULL_KEY ) {
                // Someone new sitting down
                sitAgent = agent;
                llRequestPermissions(sitAgent,PERMISSION_TRIGGER_ANIMATION);
            }
            else if ( sitAgent != NULL_KEY && agent == NULL_KEY) {
                // sitting down person got up - wake up :)
                if ( gotPermission )
                    llStopAnimation("sleep");
                // Reset the script because we don't have a way of releasing permissions :)
                llResetScript();
            }
        }        
    }
    run_time_permissions(integer parm) {
        if(parm == PERMISSION_TRIGGER_ANIMATION) {
            gotPermission = TRUE;
            llStartAnimation("sleep");
        }
    }
    
}

Youtube Video Player

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:45 +0000

Youtube Video Player

// ytv by Ziah Zhangsun
// based on the youtubeplayer by Nebadon Izume
// with some few lines of code from DanFernandez Project innerTube

string yt_url = "http://www.youtube.com/watch?v="; // base url of yt vid
string vid_id = "";                                // video_id of yt video
string vid_base = "http://www.youtube.com/get_video?fmt=18&video_id=";
string vid_url = "";
key    reqid;

string StringBetween(integer pos, string source, string start, string end)
{
    if (pos > 0)
        source = llGetSubString(source, pos, -1);
    integer sindex = llSubStringIndex(source, start);
    integer eindex = llSubStringIndex(source, end);
    if (sindex == -1 || eindex == -1)
        return "";
    else return llGetSubString(source, sindex + llStringLength(start), eindex -1);
}

default {
   
    state_entry() {
        llListen(7,"",NULL_KEY,"");     
        llOwnerSay("Ready...");         
    }

    listen( integer channel, string name, key id, string message )
    {
        if(channel == 7) {
            vid_id = message;
            reqid = llHTTPRequest( yt_url + vid_id, [], "" );
        }
    }   
   
    http_response(key id, integer status, list meta, string body) {
        if ( id != reqid )
            return;

        //llOwnerSay(body);

        integer swfArgIdx = llSubStringIndex(body, "swfArgs");
        string stringArgs = StringBetween(swfArgIdx,body,"{","}");

       
        list allArgs = llParseString2List(stringArgs,[",","\""," "],[]);

        //find argName "t" and return value ( this is the token that has to bee added to the url to access the
        //video.mp4 directy.


        integer len = llGetListLength(allArgs);
        integer i;
        string pattern = "";
        string token = "";
        for (i = 0; i < len; ++i) {

            pattern = llList2String(allArgs,i);
            if(pattern == "t") {
                token = llList2String(allArgs,i+2);
                llOwnerSay("Found Token : " + token);
                i = len; //break from loop
            }
               
        }   

        //finally, if everything goes smooth, set the generated URL to the parcell media
       
        vid_url = vid_base + vid_id + "&t=" + token;
        //llOwnerSay(vid_url);
        llParcelMediaCommandList([PARCEL_MEDIA_COMMAND_URL,vid_url]);
    }
}

move IT Home Base

Animationen

Animationen

Festhalten

Frauen-Animationen

Gehen/Laufen/Rennen

Kämpfen

Posieren

Schlafen/Liegen

Sitzen

Springen

Stehen/Posen

Tanzen

Umdrehen

Zeigen

Binary Clock

Binary Clock

Radio

Radio

Skype Online Status

Skype Online Status

Skype Online Status - Multi-User Version

Skype Online Status - Multi-User Version

Sleep

Sleep

Youtube Video Player

Youtube Video Player